過去の桐井戸端ＢＢＳ　（桐ver.８）
17219 伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を教えて下さい。 田中 2002/09/07-15:46
桐のVer8を使用しています。
現在、販売管理・在庫管理等のデータを桐Ver5→桐Ver8へ移行を始めようとしているところです。
伝票形式のフォームのヘッダ部のグループ項目において
グループ[Ａ]＝"あ"　ならば　グループ[Ｂ]に入力
グループ[Ａ]＝"い"　ならば　グループ[Ｂ]を飛ばしてにグループ[Ｃ]に入力
状態にしたいのですが、・・・・・


テキスト部において実行するイベント
手続き定義開始　t１::ソース値更新()
ケース開始
ケース　([Ａ]="あ")
メソッド呼び出し @tＢ.フォーカス設定()
ケース　([Ａ]="い")
メソッド呼び出し @tＣ.フォーカス設定()
ケース終了
手続き定義終了

をグループ項目にて実行したいのです。


書き込みの内容が通じるでしょうか？
よろしくお願いします。
17221 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 佐田　守弘 2002/09/07-17:39
記事番号17219へのコメント
田中さん
「グループ値訂正終了」イベントを使ってみて下さい。

佐田守弘(KS-00119)

17225 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 田中 2002/09/09-14:33
記事番号17221へのコメント
佐田先生、ありがとうございました。

>「グループ値訂正終了」イベントを使ってみて下さい。
>

いろいろやってみたのですが、わかりませんでした。

「グループ値訂正終了」イベントはフォーム全体において設定するようになっていましたが、

ヘッダ部のグループ項目において
グループ[Ａ]＝"あ"　ならば　グループ[Ｂ]に入力
グループ[Ａ]＝"い"　ならば　グループ[Ｂ]を飛ばしてにグループ[Ｃ]に入力状態にしたいのですが、・・・・・
グループ[Ａ]・グループ[Ｂ]・グループ[Ｃ]の各項目は、同じ伝票形式フォームの中に設定されているのですが、・・・・
具体的に
　どこの場所でのイベント(フォーム全体orグループ[Ａ])
　グループ値訂正終了の後のイベントの内容
等につきまして、再度ご教授いただきたく、よろしくお願いいたします。



17226 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 今村　誠 2002/09/09-15:21
記事番号17219へのコメント
田中さんこんにちは
>伝票形式のフォームのヘッダ部のグループ項目において
>グループ[Ａ]＝"あ"　ならば　グループ[Ｂ]に入力
>グループ[Ａ]＝"い"　ならば　グループ[Ｂ]を飛ばしてにグループ[Ｃ]に入力
>状態にしたいのですが、・・・・・

>手続き定義開始　t１::ソース値更新()
>ケース開始
>ケース　([Ａ]="あ")
オブジェクト操作 @tＣ.フォーカスの設定 = "禁止"
>ケース　([Ａ]="い")
オブジェクト操作 @tＢ.フォーカスの設定 = "禁止"
>ケース終了
>手続き定義終了
行かないようにすれば次の項目に飛ぶと思います。

17228 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 田中 2002/09/09-16:15
記事番号17226へのコメント
今村さん　コメントありがとうございます。

>手続き定義開始　t１::ソース値更新()
>>ケース開始
>>ケース　([Ａ]="あ")
>オブジェクト操作 @tＣ.フォーカスの設定 = "禁止"
>>ケース　([Ａ]="い")
>オブジェクト操作 @tＢ.フォーカスの設定 = "禁止"
>>ケース終了
>>手続き定義終了
>行かないようにすれば次の項目に飛ぶと思います。
>
試してみましたが、グループ[Ａ]に"あ"と入力しても、"い"と入力しても、グループ[Ａ]→グループ[Ｂ]→グループ[Ｃ]の順に飛びました。
上記と同じようにイベントを定義したつもりなのですが・・・
なにか、思い当たる点がありましたら、教えて下さい。よろしくお願いいたします。
17232 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 アックン 2002/09/09-19:12
記事番号17219へのコメント
田中さん、こんばんは。
こんなふうにしてみてはどうでしょう。
**-------------------------------
proc　uＡ::ソース値更新()
　　　var 文字列{ &Ａ }
　　　method　，戻り値 = &時 ，@uA.グループソース値取得( &Ａ ，0 )
　　　if( &時=1 )　/* ←ここの戻り値は 1 で良かったと記憶してますが、はっきりしてません
です。(^^; */
　　　　　if( &Ａ="あ" )
　　　　　　　method　戻り値 = &秒，@uＢ.フォーカス設定検査()
　　　　　　　if( &秒=1 )
　　　　　　　　　method @uＢ.フォーカス設定()
　　　　　　　end
　　　　　else if( &Ａ="い" )
　　　　　　　method　戻り値 = &秒，@uＣ.フォーカス設定検査()
　　　　　　　if( &秒=1 )
　　　　　　　　　method @uＣ.フォーカス設定()
　　　　　　　end
　　　　　end
　　　end
end
**-------------------------------

・欧文表記
proc　 手続き定義開始
var　 変数宣言
method　メソッド呼び出し

・説明
グループ値を取得するには「グループソース値取得」メソッドを利用します。
（似た名まえで「ソース値取得」メソッドというのがありますが、別ものです。）

思うように動かないときは、次の点をチェックしてください。
・グループ追加開始・グループ追加終了イベント等を使用しない。
・更新モードを切り替えない。
　　method　@フォーム.更新モード設定( 0 )
　　method　@フォーム.更新モード設定( 2 )
　　method　@フォーム.更新モード設定( 36 )
　　method　@フォーム.更新モード設定( 34 )　など。

**--------------
７ヶ月ぶりに掲示板をのぞいてみました。
また消えます。　アックン(=^・^=)
17233 Re:伝票形式フォームのヘッダ部のグループ項目において入力制御する方法を誰か教えて下さい。 今村　誠 2002/09/09-20:31
記事番号17228へのコメント
手続き定義開始　t１::ソース値更新()
ケース開始
ケース　([Ａ]="あ")
オブジェクト操作 @tＣ.フォーカスの設定 = "禁止"
ケース　([Ａ]="い")
オブジェクト操作 @tＢ.フォーカスの設定 = "禁止"
ケース　その他
オブジェクト操作 @tＢ.フォーカスの設定 = "禁止"
オブジェクト操作 @tＣ.フォーカスの設定 = "禁止"
ケース終了
手続き定義終了


>試してみましたが、グループ[Ａ]に"あ"と入力しても、"い"と入力しても、グループ[Ａ]→グル
>ープ[Ｂ]→グループ[Ｃ]の順に飛びました。上記と同じようにイベントを定義したつもりなので
>すが・・・
>なにか、思い当たる点がありましたら、教えて下さい。よろしくお願いいたします。
アックンさんも書いていますが、両方のケースに該当していないから、うまくいっていないと思います。
確認　で値が入っているのを確かめるのも一つの方法ですが、
ケース　その他
に両方禁止するを作成して実験されてみてはいかがでしょうか。

当方のグループ項目での記述例で参考になるかわかりませんが一応書いてみます。

手続き定義開始　g請求発行日::ソース値更新()
　　method　@g請求発行日.グループソース値取得(&現在年月日時,0)
　　method　@sw請求明細.@g税抜御買上金額.グループソース値取得(&今月売上高,1)
　　method　@sw請求明細.@g消費税額.グループソース値取得(&今月消費税,1)
　　if　(&現在月日<>&現在年月日時 .AND &現在年月日時<>"")
　　　　グループ値代入　[請求書印刷状態]="未印刷"
　　end
　　if　([前月繰越高]="")
　　　　グループ値代入　[前月繰越高]=&前月請求高
　　end
　　if　([今月売上高]="")
　　　　グループ値代入　[今月売上高]=#NUM(&今月売上高)
　　end
　　if　([今月消費税]="")
　　　　グループ値代入　[今月消費税]=#NUM(&今月消費税)
　　end
　　if　([前月繰越高]<>"")
　　　　オブジェクト操作 @ｔ前月繰越高.フォーカスの設定 = "禁止"
　　end
手続き定義終了

17238 Re:成功しました 田中 2002/09/10-13:03
記事番号17232へのコメント
アックンさん　ありがとうございました。感謝感激です!!
成功しました。ばっちり飛びました。
ただ、知識不足のため、何でこうなるのかがわかりません。
この後、じっくりと勉強しなければ・・・。

>７ヶ月ぶりに掲示板をのぞいてみました。
>また消えます。　アックン(=^・^=)

消えるのは、これを読んでからにして下さい。一番いいのは、消えないで今後も何かあったときご助言いただければ・・・なんですが


本当に本当にありがとうございました。

17239 Re:ありがとうございました 田中 2002/09/10-13:14
記事番号17233へのコメント
今村　誠さん　ありがとうございました。

自分の知識不足のため、エラーをおこさせてしまいました。
今回は、アックンさんのでうまくいきましたので、そちらでやってみます。

また、参考となる記述例を掲載していただいて、ありがとうございます。


戻る