過去の桐井戸端ＢＢＳ　（桐ver.９）
21052 1つのtblに何度も同じ操作をしない効率的なイベントの書き方を教えて下さい。 しぼうかん 2003/06/22-18:44
またお世話にならせて下さい。よろしくお願いします。

受注.wfm(対象表=受注.tbl　伝票形式　セクション分割=3)
オブジェクト[〒]と[住所]

住所A.wfm(対象表=住所.tbl　伝票形式)オブジェクト[〒]と[住所]

住所B.wfm(対象表=住所.tbl　一覧形式)オブジェクト[〒]と[住所]

※1.の方法をとる場合、住所B.wfmはフォームの幅や高さが大きいので
受注.wfmのオブジェクトにかぶってしまいフォーム編集の邪魔になるので
3.の処理をするだけの為に小さなフォームの住所A.WFMを作り、
受注.wfmにサブフォームとして貼り付けて置きます。
(これはサイズ変更しないでワークスペースに置いても同じでしょうが。)


受注.wfmを開くときに

1.住所A.wfm(対象表=住所.tbl)を受注.wfmのサブフォーム(非表示)として同時に開く

2.受注.wfmのフォーム開始イベントで住所.tblを開く

1.か2.のどちらかの方法で住所.tblを開いて置きます。

※下記の処理をする場合どちらがいいのかわからないのでとりあえず
2.の方法でイベントを書いて見ましたが違いが有る場合はどちらの方法がいいかもお聞きしたいのです。

3.受注.wfmの[住所]の入力前イベントで[〒]のソース値を&〒に代入し、
住所.tblの[〒]を&〒で絞り込み&選択件数に絞り込み件数を代入します。

4.&選択件数が0の場合は何もしないでイベントを終了させます。

5.&選択件数が1以上の場合は住所B.wfmを開いて入力したい住所があればカーソルで選んでEnterキーを押します。

6.住所B.kev(フォーム=住所B.wfm)のキーダウンイベントでEnterキーを押した時には[住所]のソース値を&住所に代入して、
編集表を受注.wfmに切り替えて[住所]の&編集文字列に&住所を代入したいのです。

以上の事をしたくて下記の様なイベントを書いたのですが住所.tblの
サイズが大き過ぎて処理が遅いのでやり方やイベントの書き方を工夫して
なんとか処理をもう少し速く出来ないか考えています。

住所.tblを&選択件数を求める為に絞り込みを実行後、住所B.wfmを使って
多重化した同じ住所.tblに対してもう一度同じ絞り込みを実行するのは
おかしなやり方だと思いつつも他に方法がわかりません。

また既に開いている住所.tblを対象表として住所B.wfmを開く事が出来れば
多重化して開いた住所B.wfmで同じ絞り込みを2度もしなくてよくなるので
処理速度が速くなると思うのですがこの方法もよくわかりません。

手順の流れとしては1.又は2.の後3.を行い4.の時はイベント終了。
5.の時は6.の後イベント終了としたいのです

お分かりの方は部分的なヒントだけでも結構ですのでご教授下さい。

大きくなってしまったので次のツリーにイベント処理を書きます

21053 タイトルが長すぎてすいません。 しぼうかん 2003/06/22-18:47
記事番号21052へのコメント
受注.wfmの受注.kev


手続き定義開始　住所::入力前(参照　文字列　&編集文字列)
メソッド呼び出し　@〒.ソース値取得(&〒,0)
メソッド呼び出し　@住所.ソース値取得(&住所1,0)
ケース開始
ケース(&住所="")
編集表　住所.tbl
絞り込み　[住所]{[〒]=&〒}
ケース開始
ケース(&選択件数=>1)
絞り込み解除　*
フォーム呼び出し　"住所B",許可作業=*,編集表=しない
ケース開始
ケース(&住所><"")
&編集文字列=&住所
ケース終了
ケース　その他
絞り込み解除　*
終了　表　編集対象表
ケース終了
ケース終了
手続き定義終了


住所B.wfmの住所B.kev
※索引とフォーム開始時の並べ替え条件は設定済


手続き定義開始　フォーム::キーダウン(長整数　&仮想キーコード，長整数　&スキャンコード，長整数　&フラグ，参照　長整数　&処理中止)
ケース開始
ケース(&仮想キーコード=13)
&住所=[住所]
メソッド呼び出し　@終了.実行()
ケース(&仮想キーコード=27)
メソッド呼び出し　@終了.実行()
ケース終了
手続き定義終了


手続き定義開始　フォーム::フォーム開始(長整数　&表番号)
絞り込み　[〒]{[〒]=&〒}
ケース開始
ケース(&選択件数=>1)
メソッド呼び出し　ハンドル=&hwindow,@住所.フォーカス設定()
ケース　その他
メソッド呼び出し　@終了.実行()
ケース終了
手続き定義終了


手続き定義開始　フォーム::フォーム終了()
絞り込み解除　*
手続き定義終了

@終了は機能名=閉じるのコマンドボタンです。

21054 Re:1つのtblに何度も同じ操作をしない効率的なイベントの書き方？それとも方法？を教えて下さい。 うにん 2003/06/22-20:18
記事番号21052へのコメント
結局住所A.wfmは全く使っていないので、最初から住所B.wfmを非表示で開いて
そっちで絞り込みすればいいんじゃないでしょうか？

21055 バッサリ 悲しげ 2003/06/22-21:48
記事番号21053へのコメント
>3.の処理をするだけの為に小さなフォームの住所A.WFMを作り、

うにんさんも仰るとおり、「3.の処理」すなわち「住所A.WFM」の
存在意義が伝わって来ません。
つー訳で、浅読かつ誤読に基づいて、それらをバッサリとカットして大胆かつ無責任に書き換えると(^^;)

手続き定義開始　住所::入力前(参照　文字列　&編集文字列)
　&〒=[〒],&住所=[住所]
　if(&住所="")
　　表　"住所.tbl",索引名="〒順"
　　絞り込み　[〒]{&〒}　/*索引を使うと速い筈*/
　　＊絞り込み　[〒]{&〒*}　/*先頭一致検索の場合*/
　　if(&選択件数>0)
　　　フォーム呼び出し　"住所B.wfm",編集表=する
　　　/*「編集表=する」で絞り込み状態をそのまま継承させた*/
　　　条件(&住所)　&編集文字列=&住所
　　end
　　終了　表　編集対象表
　end
手続き定義終了

住所B.wfmの住所B.kev
上述のとおり「編集表=する」で絞り込み状態を継承させているので、
索引やフォーム開始時の並べ替え条件は不要か？？？

手続き定義開始　フォーム::キーダウン(長整数　&仮想キーコード，・・・・
　if(&仮想キーコード=13)
　　&処理中止=1,&住所=[住所]
　　メソッド呼び出し　@終了.実行()
　else if(&仮想キーコード=27)
　　確認　"中止しますか？",&実行リターン
　　if(&実行リターン<>1)
　　　&処理中止=1
　　else
　　　&住所=""
　　　＊メソッド呼び出し　@終了.実行()
　　　/*↑フォーム呼び出しでは特に指定しない限り[Esc]で勝手に閉じます*/
　　end
　end
手続き定義終了

手続き定義開始　フォーム::フォーム開始(長整数　&表番号)
　＊絞り込み　[〒]{[〒]=&〒}
　＊ケース開始
　＊ケース(&選択件数=>1)
　メソッド呼び出し　@住所.フォーカス設定()　　/*これだけ(^^;)*/
　＊ケース　その他
　＊メソッド呼び出し　@終了.実行()
　＊ケース終了
手続き定義終了

手続き定義開始　フォーム::フォーム終了()
　＊絞り込み解除　*　　/*不要？？*/
手続き定義終了

21056 別件的補足 悲しげ 2003/06/22-22:12
記事番号21055へのコメント
別件になりますが補足です。
　　メソッド呼び出し　@〒.ソース値取得(&〒,0)
　　メソッド呼び出し　@住所.ソース値取得(&住所1,0)
の部分を大胆に
　　&〒=[〒],&住所=[住所]
に書き換えさせて戴きました。@〒,@住所のテキストソースはそれぞれ
[住所],[〒]に確定しているだろうと浅読みさせてもらったからです。
以下その前提で続けますと──
しぼうかんさんは「ソース値取得」メソッドがお好きなようですが(^^;)、
これは一般にはテキストソースが特定できないような場合に使います。
いえ、特定できる場合に使っても支障はないのですが、ちょいと大げさです。
このことを以前に、確か山手線の内回り・外回りの喩えでお話したことがありますが、
判りにくかったみたいなので、今度は別な喩えを挙げてみます。
（余計に判りにくくするだけかもしれませんが）
え〜（「代入」コマンドを省略してしまってますけど）
　　&〒=[〒],&住所=[住所]
の場合は、明らかに目の前にあるものを素手でつかむイメージ。
片や「ソース値取得」メソッドは、脚立（きゃたつ）を使って、
手の届かないような高い所にあるものを取るようなイメージ。
すぐ目の前にあるものを取るのに、脚立を持って来てそれに乗ってから
掴むことは可能ではありますが、普通はそのまま素手で取ると思います。

つー訳で、どうでしょう？　山手線の話と比べて。(^^;)
21063 何とか解決しましたがもう少しだけ教えて下さい。 しぼうかん 2003/06/23-18:44
記事番号21054へのコメント
うにんさん、早速のお返事ありがとうございます。


>結局住所A.wfmは全く使っていないので、


1.の様に受注.wfmのサブフォームとして住所A.wfmを使って
住所.tblを開くのと、2.の様に受注.wfmのフォーム開始イベントで
住所.tblを開くのでは後でイベント処理をする時に何か違いが
出るかもしれないと思い２つの方法を考えて見たのですが、
1.の住所A.wfmを使う方法は意味がなかったみたいです。

今回は悲しげさんに教えて頂いた方法でうまく行きましたが、
後学の為にうにんさんの方法についてもお聞きしたいのですが、


>最初から住所B.wfmを非表示で開いてそっちで絞り込みすれば
>いいんじゃないでしょうか？


この言葉の意味は、受注.wfmの受注.kevの"編集表　住所.tbl"の行から
"絞り込み解除　*"の行までは必要なくて、次の行の　

フォーム呼び出し　"住所B",許可作業=*,編集表=しない

で呼び出す住所B.wfmを非表示で呼び出し、呼び出した住所B.wfmの
フォーム開始イベントで絞り込みを行い１行以上絞り込めた場合は
住所B.wfmを表示させるという様な事が出来る、という意味なのでしょうか？　

21064 新タイトル"フォーム呼び出し"の使い方？(解決しました。) しぼうかん 2003/06/23-18:54
記事番号21056へのコメント
悲しげさん、いつもお世話になっています。

教えて頂いた通りの方法でうまく行きました。
ありがとうございました。m(_ _)m

"編集表＝する"という設定とすでに開いている住所.tblを絞り込んで
その同じ住所.tblを編集対象表とする住所B.wfmをフォーム呼び出しで
開く事、つまりすでに開いている表にフォームを後から開いて
くっつける様な感じの事？が出来るとは勉強不足で知りませんでした。

ソース値更新と代入の違いについての講義よくわかりました。(^_^)

以前は項目値の変数への代入には殆どソース値取得を使っていたのですが
以前、悲しげさんに指摘して頂いてから、どちらでも良い場合は原則として
代入を使っていましたが(悲しげさんがおっしゃっている様な深い意味を
考えた訳では無くて単純に文字数が少なく行数も少なくなるという理由でした。)
癖がまだ抜けず今回うっかり使ってしまいました。


PS
どうでもいい情報です。
K3はこんなHPも持っているんですね。
http://toybox.kthree.co.jp/Puga/html/index1.html
21065 Re:新タイトル"フォーム呼び出し"の使い方？(解決しました。) hidetake 2003/06/23-20:08
記事番号21064へのコメント
>K3はこんなHPも持っているんですね。
>http://toybox.kthree.co.jp/Puga/html/index1.html

スミマセン？　桐には直接関係ない話だけれど・・・ _o_

これは【多遊】さんのところでも以前出しましたが
http://www2u.biglobe.ne.jp/~s_tanaka/cgi-bin/bbs/bbs.cgi?function=logview_html&no=70#3452
http://www2u.biglobe.ne.jp/~s_tanaka/cgi-bin/bbs/bbs.cgi?function=logview_html&no=63#3138

しかし，ここのサイトにも今時にしては，セキュリティは
あまり考えていないのか XSS欠陥はありますねぇ〜　(-_-;

http://toybox.kthree.co.jp/Puga/cgi/problems.cgi?kind=%22%3E%3Cscript%3Ealert%28document.cookie%29%3C/script%3E%3C%22

参考情報
クロスサイトスクリプティング脆弱性とその対策の要領
http://www.ipa.go.jp/security/awareness/vendor/programming/a01_02.html


21066 Re:何とか解決しましたがもう少しだけ教えて下さい。 うにん 2003/06/23-22:35
記事番号21063へのコメント
>>最初から住所B.wfmを非表示で開いてそっちで絞り込みすれば
>>いいんじゃないでしょうか？

方法というほど深く考えてたわけじゃないのですが(^^;

>で呼び出す住所B.wfmを非表示で呼び出し、呼び出した住所B.wfmの
>フォーム開始イベントで絞り込みを行い１行以上絞り込めた場合は
>住所B.wfmを表示させるという様な事が出来る、という意味なのでしょうか？　

フォームは使用フォームコマンドでいつでも開けるので検索するために
住所A.wfmを使う必要はなさそう、という程度の意味でした。
非表示というのは、
ウィンドウ作成　"住所B.wfm",オプション＝非表示,編集表＝開く
のようなことです。
しかし、オーバーラップフォームには使えませんね。

21067 Re:新タイトル"フォーム呼び出し"の使い方？(解決しました。) 悲しげ 2003/06/23-23:14
記事番号21064へのコメント
ちなみにタイトルで曰く「フォーム呼び出しの使い方」とは云っても、
「編集表=する」がこの場合の唯一のやり方ではありません。
このパラメータを省略すると「編集表=しない」となるところ、敢えて
「編集表=しない」を明記してあったので、それならば……と云うこと
で挙げてみたと云うことです。
「編集表=しない」でやるとしたら、次のようになるかと思います。

手続き定義開始　住所::入力前(参照　文字列　&編集文字列)
　&〒=[〒],&住所=[住所]
　if(&住所="")
　　フォーム呼び出し　"住所B.wfm"
　　/*「編集表=」をパラメータを省略している→「編集表=しない」*/
　　&編集文字列=&住所
　end
手続き定義終了

この場合、住所B.kevの「フォーム開始」での記述は次のようにします。

手続き定義開始　フォーム::フォーム開始(長整数　&表番号)
　/*開始条件での索引指定は必要*/
　絞り込み　[〒]{&〒}
　if(＆選択件数>0)
　　メソッド呼び出し　@住所.フォーカス設定()
　else　　/*★*/
　　メソッド呼び出し　@終了.実行()
　end
手続き定義終了

ただ、★印の場合、フォームが一旦チラリと表示されてしまうと思われます。
これを見苦しいと思えば、それなりに料理する必要がありそうです。

ま、編集表パラメータのする・しないの何れの場合でも、住所.tblはひとつしか開いていません。
少なくともオリジナルのように三重に開く必要はありません。

＊

>また既に開いている住所.tblを対象表として住所B.wfmを開く事が出来れば
>多重化して開いた住所B.wfmで同じ絞り込みを2度もしなくてよくなるので
>処理速度が速くなると思うのですがこの方法もよくわかりません。

深読みのし過ぎかもしれませんが、もしこの部分（三重オープン）が、
たまたま話題に上っている「多重化表の利用による高速化」への期待によっているのだとしたら、
この場合は全く関係ありません。
今回の件は画面への描画ゆえに遅くなっている訳ではないからです。
多重化表を使って処理を高速化できるのは、描画による遅延が発生している場合などでしょうから。

21072 Re:新タイトル"フォーム呼び出し"の使い方？(解決しました。) ONnoji 2003/06/24-12:36
記事番号21067へのコメント
しぼうかんさん、こんにちは。

悲しげさん、横レスで失礼します。m(__)m

>以上の事をしたくて下記の様なイベントを書いたのですが住所.tblの
>サイズが大き過ぎて処理が遅いのでやり方やイベントの書き方を工夫して
>なんとか処理をもう少し速く出来ないか考えています。
>また既に開いている住所.tblを対象表として住所B.wfmを開く事が出来れば
>多重化して開いた住所B.wfmで同じ絞り込みを2度もしなくてよくなるので
>処理速度が速くなると思うのですがこの方法もよくわかりません。

住所.tbl ツーのは相当大きいのでしょうね。

ならば、索引を使用したらいかがでしょうか？

私の手持ちの一番大きな表( .tbl )で次のような実験をしてみましたが…
やはり、索引を使って［検索］や［絞り込み］をしたほうが早いですね。

なお、部分一致や and or などの［検索］や［絞り込み］では索引の効果はないと思います。
効果があるのは完全一致と先頭一致の場合だけです（当たり前ですが…）。

コマンド以外の場面でも自動的に索引を使ってくれる可能性が期待できないわけでもないかな〜…自信なし(^^ゞ

■実験.kev
*-----------------------------*
名札 メイン
　変数宣言　局所，文字列｛ &mString = "○○" ｝
＊

手続き定義開始　cmd索引無し検索Click( )
　解除 *
　＊検索　[書籍名]｛ &mString ｝
　絞り込み　[書籍名]｛ &mString ｝
手続き定義終了

手続き定義開始　cmd索引有り検索Click( )
　変数宣言　自動，文字列｛ &string ｝
　&string = """" + &mString + """*"
　解除 *
　並べ替え　索引名 = "書籍名"
　＊検索　[書籍名]_&string
　＊検索　[書籍名]｛ &mString ｝
　＊絞り込み　[書籍名]_&string
　絞り込み　[書籍名]｛ &mString ｝
手続き定義終了
*-----------------------------*

一般手続き：cmd索引有り検索Click の方がスピードが速いです。
※アスタリスクでコメント化したコマンドも同速度のようです。

私の場合には、そんなに大きな表( .tbl )を扱うこともないので、
また、Windowsではキャッシュの効果が大きいので、
いままで索引を使用した［検索］や［絞り込み］は行っていません。
なお、併合処理の時には索引を暗示的や明示的に使いますが…

ネットワークがネックになっているなら話は別ですが…(^^ゞ

>深読みのし過ぎかもしれませんが、もしこの部分（三重オープン）が、た
>またま話題に上っている「多重化表の利用による高速化」への期待によっ
>ているのだとしたら、この場合は全く関係ありません。
>今回の件は画面への描画ゆえに遅くなっている訳ではないからです。多重
>化表を使って処理を高速化できるのは、描画による遅延が発生している場
>合などでしょうから。

悲しげさん、御意です。

フォームの再描画のためにスピードが低下するなら、
「すっぽん」エキスが効果的ですね。(^^ゞ
通販できますか？

21074 Re:バッサリ 悲しげ 2003/06/24-14:01
記事番号21055へのコメント
ところで、#21055の記述に★印部分を挿入して

手続き定義開始　住所::入力前(参照　文字列　&編集文字列)
　&〒=[〒],&住所=[住所]
　if(&住所="")
　　表　"住所.tbl",索引名="〒順"
　　絞り込み　[〒]{&〒}　/*索引を使うと速い筈*/
　　＊絞り込み　[〒]{&〒*}　/*先頭一致検索の場合*/
　　if(&選択件数>0)
　　　フォーム呼び出し　"住所B.wfm",編集表=する
　　　/*「編集表=する」で絞り込み状態をそのまま継承させた*/
　　　条件(&住所)　&編集文字列=&住所
　　else　　/*★*/
　　　確認 "〒"+&〒+" is NOT found → 要〒再入力哉?"
　　　メソッド呼び出し　@〒.フォーカス設定()
　　end
　　終了　表　編集対象表
　end
手続き定義終了

のようにできればいいかもしれませんけれどもが、だがしかし
「入力前」イベントから入る限りはフォーカスの移動はできま
せんから、この辺りは発想の転換が必要かも。
21076 Re:バッサリ２ ONnoji 2003/06/24-14:22
記事番号21074へのコメント

>　　表　"住所.tbl",索引名="〒順"
>　　絞り込み　[〒]{&〒}　/*索引を使うと速い筈*/
>　　＊絞り込み　[〒]{&〒*}　/*先頭一致検索の場合*/

悲しげさん、こんにちは。

すでに索引のことは話題に上がっていたんですね。
すいません、流し読みなもので気が付いていませんでした。(^^ゞ

せっかく悲しげさんがヒントを書いていらっしゃるのに…
しぼうかんさんは本当に索引を利用して試したのでしょうかね？？？

＜蛇足＞

なお、表( .tbl )にバックアップ指定があると、
その表( .tbl )を開くときに時間がかかります。
更新後に閉じる時にも時間がかかります。

［表］コマンドなら、モード = 参照　とか…

いっそのこと思いきって、表( .tbl )を　バックアップ＝しない　とか…

まさか、遅い遅いというのは、このことではありませんよね。


21078 Re:バッサリ うにん 2003/06/24-14:34
記事番号21074へのコメント
>　　else　　/*★*/
>　　　確認 "〒"+&〒+" is NOT found → 要〒再入力哉?"
>　　　メソッド呼び出し　@〒.フォーカス設定()
>　　end
>　　終了　表　編集対象表
>　end
>手続き定義終了
>
>のようにできればいいかもしれませんけれどもが、だがしかし
>「入力前」イベントから入る限りはフォーカスの移動はできま
>せんから、この辺りは発想の転換が必要かも。

再入力が必要ってことは〒が不正ということですから、そっちの
「入力後」でチェックするってことになるでしょうね。

21087 悲しげ薬局はアフターケアも万全ですね。 しぼうかん 2003/06/24-21:48
記事番号21074へのコメント
悲しげさん、アフターケアまでどうもありがとうございます。


>ただ、★印の場合、フォームが一旦チラリと表示されてしまうと
>思われます。これを見苦しいと思えば、それなりに料理する必要が
>ありそうです。


世の中には"チラリ"と見えてうれしい物もありますが、
これはちょっと違いますね。(^_^)

実は一番最初に書いた単純なコマンドではこの"チラリ"が有り
精神衛生上良くないと思いこの"チラリ"を無くすため最初の投稿の様な
"フォーム呼び出しコマンドの前に絞り込みデータがあるかどうか確認の為の
コマンドを書いてデータが有ることを確認後にフォーム呼び出しを行う"
という２段階方式のコマンドを書いた訳です。

しかし同じファイルに同じ操作を１度目はデータの存在の確認、２度目は
フォーム呼び出しの為と２度繰り返すのは"スピードも遅くなるはずだし、
多分書き方が間違っているな"と思い投稿させてもらいました。

おかげさまで"チラリ"も"重複処理"も無くうまく出来ました。

〒番号は必ずしも入力されていなくても良いフォームなので〒番号が
無いときはそのまま次の項目へフォーカス移動する様にしています。

この受注.tblを使って商品を発送するときは郵便局を使わないで民間業者を使うので、
[住所]さえしっかりしていればいいので、[〒]は単に住所の
入力補助項目として使っています。
21088 返信ありがとうございます。 しぼうかん 2003/06/24-21:59
記事番号21076へのコメント
ONnojiさん、こんばんは.

返信有り難うございます。

住所.tbl(本名はZIP.tbです)は佐田先生の所からダウンロードした
ファイルで20MBありましたが少し削って今は14MBです。

そのほかに投稿内容が大きくなりすぎるので省略したのですが、この
[住所]の入力前イベントでは[得意先]と[発送先]を変数に取り、
多重化した受注多重化.wfm(受注.tbl)でまず[〒]では無くて
[得意先]+[発送先]を検索して希望のレコードが無い場合は
昨年の受注.tblで[得意先]+[発送先]を検索し、そこでも
希望のレコードが無い場合に住所.tblから[〒]を検索して[住所]を
取り出すというコマンドが書いてあります。

そこで３つの検索をそれぞれ単独で検索して見たところ
住所.tblを使って検索する部分が一番時間がかかるようなので
この部分だけを投稿しました。

そして、悲しげさんに教えて頂いた索引を使う方法はちゃんと使わせて頂きました。

おかげでかなり入力前イベントの待機時間が1〜2秒から0.？秒になり
ストレス無く入力出来るようになりました。

"為になる蛇足"の所に書いてあった"バックアップ指定をはずすと
さらに早くなる"と"なお、部分一致や and or などの［検索］や
［絞り込み］では索引の効果はない"と言うことは知りませんでした。

そこでさっそくその部分を見てみるとバックアップ指定がしてありませんでした。
(もともと指定して無かったか、別件でハズしたのかも
しれません。)検索方法は完全一致でしたので問題なしでした。

今回は偶然問題無しでしたが、おかげさまで次からは意識して
コマンドを書く事が出来るようになりました。


>［表］コマンドなら、モード = 参照　とか…


すいません、最後にもう少しだけ説明して頂きたいのですが、この部分の
意味がわからないのですが、まだ何か処理が早くなる方法があるのでしょうか？

21089 ご回答ありがとうございました。 しぼうかん 2003/06/24-22:04
記事番号21078へのコメント
うにんさん、ご回答ありがとうございました。

ウインドウ作成コマンドのオプションで非表示が出来るのですか。

過去ログで、ある方がウインドウ作成より、フォーム呼び出し
(自動的にモーダルフォームになる為)の方が制御が簡単で有利くさい
という様なご意見を述べられていた様な気がしたのであまり使った事が
なかったのですが、こんな使い方が出来るとは、勉強させて頂きました。
フォーム呼び出しで対応出来ない別の機会があれば試してみたいと思います。


>再入力が必要ってことは〒が不正ということですから、そっちの
>「入力後」でチェックするってことになるでしょうね。


〒番号は必ずしも入力されていなくても良いフォームなので〒番号が
無いときはそのまま次の項目へフォーカス移動する様にしています。

この受注.tblを使って商品を発送するときは郵便局を使わないで民間業者を使うので、
[住所]さえしっかりしていればいいので、[〒]は単に住所の
入力補助項目として使っています。
　　
21090 Re:返信ありがとうございます。 ONnoji 2003/06/24-22:08
記事番号21088へのコメント
しぼうかんさん、こんばんは。

>おかげでかなり入力前イベントの待機時間が1〜2秒から0.？秒になり
>ストレス無く入力出来るようになりました。

なるほど、速くなりますね。

今まで私はちょっと位遅くても、まあいいや〜としていましたが、
速いに越したことはありませんね。

>>［表］コマンドなら、モード = 参照　とか…
>すいません、最後にもう少しだけ説明して頂きたいのですが、この部分の
>意味がわからないのですが、まだ何か処理が早くなる方法があるの
>でしょうか？

参照で開いた場合には、バックアップなしと同じだったという記憶ですが、
バックアップなしの表の場合には効果はないと思います。

バックアップなしというのは、
処理が早くなるという意味ではなく、
開くまでの時間と閉じる時間が短くなるという意味です。


21091 Re:新タイトル"フォーム呼び出し"の使い方？(解決しました。) しぼうかん 2003/06/24-22:09
記事番号21065へのコメント
hidetakeさん、こんばんは.

既出でしたか、残念!

あとのコメントは私の知識と能力では？でした。
21092 了解しました。 しぼうかん 2003/06/24-22:12
記事番号21090へのコメント
ONnojiさん、了解しました。

ご説明ありがとうございました。

※リアルタイムで答えることが出来たのはこれがはじめてかも？
21258 返答のお礼を忘れてました。 しぼうかん 2003/07/03-21:08
記事番号21066へのコメント
うにんさん、返答のお礼を忘れていました。
失礼致しました。ありがとうございました。

戻る